Получить список переданных аргументов в пакетном скрипте Windows (.летучая мышь)

%* кажется, содержит все аргументы, переданные скрипту.

%1 ... %n и %* содержит аргументы, но это может быть сложно получить к ним доступ, потому что содержание будет интерпретироваться.
Поэтому невозможно справиться с чем-то подобным с обычными утверждениями

myBatch.bat "&"^&

каждая строка терпит неудачу, как cmd.exe попробуйте выполнить один из амперсандов (содержимое %1 "&"&)

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

но существует обходной путь с временным файлом

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

фокус в том, чтобы включить echo on и расширить %1 после a rem оператор (работает также с %2 .. %*).
Но чтобы иметь возможность перенаправить вывод echo on, вам нужны два FOR-LOOPS.

лишние символы * # используются для защиты от содержимого, такого как /? (покажет помощь для REM).
Или каретка ^ в конце строки может работать как многострочный символ.

FOR / F должен работать с отложенным расширением, иначе содержимое с "!" должен быть разрушенный.
После удаления лишних символов param1 и вы его получили.

и использовать param1 безопасным способом включите отложенное расширение.

изменить: одно замечание к %0

%0 содержит команду, используемую для вызова пакета, также сохраняя регистр, как в FoO.BaT
Но после вызова функции %0 а также в %~0 содержит имя функции (или лучше строку, которая использовалась для вызова функция.)
Но с %~f0 вы все еще можете вспомнить имя файла.

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

выход

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat

я обнаружил, что в следующий раз, когда вам нужно посмотреть эту информацию. Вместо того, чтобы открыть браузер и google его, вы можете просто ввести call /? в cmd и вы получите это:

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*

способ получить все args в скрипт здесь:

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause

здесь есть довольно простой способ, чтобы получить args и установить их как переменные окружения. В этом примере я буду просто ссылаться на них как на ключи и значения.

сохранить в следующем примере кода в качестве "аргумента.летучая мышь." Затем вызовите пакетный файл вы сохранили из командной строки. пример: арг.bat --x 90 --y 120

Я предоставил некоторые команды echo, чтобы вы прошли через этот процесс. Но конечным результатом является то, что --x будет иметь значение 90 и --y будет иметь значение 120(то есть, если вы запустите пример как указано выше ;-) ).

затем вы можете использовать условный оператор 'if defined', чтобы определить, следует ли запускать блок кода. Итак, допустим, работать: "аргумент.bat --x Привет-мир" Затем я мог бы использовать оператор " IF DEFINED --x echo %--x%", и результаты будут"hello-world". Это должно иметь больше смысла, если вы запустите пакет.

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^>         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It's important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done

следующий код имитирует массив ('params') - принимает параметры, полученные скриптом, и сохраняет их в переменных params_1 .. params_n, где n=params_0=количество элементов массива:

@echo off

rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
    set /a count+=1
    set "params_%count%=%~1"
    shift
    if defined params_%count% (
        goto :repeat
    ) else (
        set /a count-=1
    )    
set /a params_0=count

rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
    for /l %%i in (1,1,!params_0!) do (
        echo params_%%i: "!params_%%i!"
    )
endlocal

pause
goto :eof

@echo off
:start

:: Insert your code here
echo.%%1 is now:%~1
:: End insert your code here

if "%~2" NEQ "" (
    shift
    goto :start
)

много информации выше привело меня к дальнейшим исследованиям и в конечном итоге мой ответ, поэтому я хотел внести свой вклад в то, что я закончил делать в надежде, что это поможет кому-то еще:

• Я также хотел передать различное количество переменных в пакетный файл, чтобы они могли быть обработаны в файле.

• Я был в порядке с передачей их в пакетный файл, используя кавычки

• Я бы хотел, чтобы они обрабатывались так же, как показано ниже - но с помощью цикла вместо того, чтобы выписывать вручную:

поэтому я хотел выполнить это:

prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"

и с помощью магии for loops сделать это в пакетном файле:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

проблема у меня была в том, что все мои попытки использовать цикл for не работали. Пример ниже:

for /f "tokens* delims= " in %%A (%*) DO (
   set %%A
)

просто:

set "_appPath=C:\Services\Logs\PCAP"

и

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

после

SETLOCAL EnableDelayedExpansion

причина была что цикл for прочитал всю строку и назначил мой второй параметр %%B во время первой итерации цикла. Поскольку %* представляет все аргументы, есть только одна строка для обработки-ergo происходит только один проход цикла for. Это получается, и моя логика была неверной.

поэтому я перестал пытаться использовать цикл for и упростил то, что я пытался сделать, используя if, shift и оператор goto. Согласился его немного взломать, но это больше подходит для моих нужд. Я может перебирать все аргументы, а затем использовать оператор if, чтобы выйти из цикла, как только я обработаю их все.

выигрышное заявление о том, что я пытался сделать:

echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
    set %1
    shift
    goto:processArguments
) ELSE (
    echo off 
)

UPDATE-вместо этого мне пришлось изменить ниже, я выставлял все переменные среды при попытке ссылаться на %1 и использовать shift следующим образом:

echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
    set %0
    shift
    goto:processArguments
) ELSE (
    echo off 
)

Если у вас есть параметры в кавычках, содержащие пробелы,%* не будет работать правильно. Лучшее решение, которое я нашел, это иметь цикл, который объединяет все аргументы:https://serverfault.com/a/22541

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

версия Windows (требуется socat, хотя)

C:\Program Files (x86)\Git\bin>type gitproxy.cmd
socat STDIO PROXY:proxy.mycompany.de:%1:%2,proxyport=3128

настройки:

C:\Users\exhau\AppData\Roaming\npm>git config --global core.gitproxy gitproxy.cmd

можно использовать %1, %2 etc для доступа к аргументам командной строки. Я не думаю, что есть переменная, которая содержит весь список. Вы могли бы написать простой цикл, который определяет, сколько аргументов было передано.

EDIT: видимо есть:)

для тех, кто нуждается в задней косой черте из basepath

set source=%~dp0
::Remove the trailing backslash from source
IF %source:~-1%==\ SET source=%source:~0,-1%
echo %source%