Хотите получать данные GPS каждые 5 секунд с помощью arduino

Именно поэтому я написалNeoGPS . Примеры программ для всех других библиотек просто не структурированы должным образом. Я смотрю на тебя, smartDelay()...

NeoGPS структурирована вокруг получения полного fix от GPS-устройства. Обычно для этого требуется несколько предложений. Другие библиотеки GPS сообщают вам только о получении одного предложения. Кроме того, трудно сказать, относятся ли два предложения к одному и тому же 1-секундному интервалу обновления или к двум последовательным интервалы.

Вы хотите отображать информацию один раз в 5 секунд, но это может быть один раз в 20 предложений. И согласно часам Arduino millis(), это будет около 5000 мс, , но не совсем. millis() будет дрейфовать против интервала GPS, в зависимости от того, насколько точен ваш кристалл. Интервал GPS очень точен, в пределах атомных часов, последовательной скорости передачи данных и времени расчета GPS-устройства.

Вот ваш эскиз, модифицированный для использования. NeoGPS:

#include <NMEAGPS.h>
  /*
    This program sketch obtain and print the lati,logi,speed,date and time
    It requires the use of SoftwareSerial, and assumes that you have a
    9600-baud serial GPS device hooked up on pins 4(rx) and 3(tx).
   */
#include <NeoSWSerial.h>
static const int RXPin = 4, TXPin = 3;
NeoSWSerial gpsPort(RXPin, TXPin);
static const uint32_t GPSBaud = 9600;

NMEAGPS gps;
gps_fix fix;
uint8_t fixCount = 0;

void setup()
{
  Serial.begin(9600);
  gpsPort.begin(GPSBaud);

  Serial.println(F("GPS LOADING....."));
  Serial.println(F("Obtain and print lati,logi,speed,date and time"));
  Serial.println(F("Testing by : "));
  Serial.println(F("Billa"));
  Serial.println();
}

void loop()
{
  while (gps.available( gpsPort )) {
    fix = gps.read();

    // Once every 5 seconds...    
    if (++fixCount >= 5) {
      displayInfo();
      fixCount = 0;
    }
  }

  if ((gps.statistics.chars < 10) && (millis() > 5000)) {
     Serial.println( F("No GPS detected: check wiring.") );
     while(true);
  }
}

void displayInfo()
{
  Serial.print(F("Location: ")); 
  if (fix.valid.location) {
    Serial.print( fix.latitude(), 5 );
    Serial.print( ',' );
    Serial.print( fix.longitude(), 5 );
  } else {
    Serial.print(F("INVALID"));
  }

  Serial.print(F("  Speed: ")); 
  if (fix.valid.speed) {
    Serial.print(fix.speed_kph());
    Serial.print(F(" KMPH "));
  } else {
    Serial.print(F("INVALID"));
  }

  // Shift the date/time to local time
  NeoGPS::clock_t localSeconds;
  NeoGPS::time_t  localTime;
  if (fix.valid.date && fix.valid.time) {
    using namespace NeoGPS; // save a little typing below...

    localSeconds = (clock_t) fix.dateTime; // convert structure to a second count
    localSeconds += 5 * SECONDS_PER_HOUR + 30 * SECONDS_PER_MINUTE; // shift timezone
    localTime = localSeconds;              // convert back to a structure
  }

  Serial.print(F("  Date : "));
  if (fix.valid.date) {
    Serial.print(localTime.month);
    Serial.print('/');
    Serial.print(localTime.date);
    Serial.print('/');
    Serial.print(localTime.year);
  } else {
    Serial.print(F("INVALID"));
  }

  Serial.print(F("  Time : "));
  if (fix.valid.time) {
    Serial.print(localTime.hours);
    Serial.print(':');
    if (localTime.minutes < 10) Serial.print('0');
    Serial.print(localTime.minutes);
    Serial.print(':');
    if (localTime.seconds < 10) Serial.print(F("0"));
    Serial.print(localTime.seconds);
  } else {
    Serial.print(F("INVALID"));
  }

  Serial.println();
}

Этот эскиз отображает каждый пятый fix, не используя неточный millis() или неприятный delay(). Ни у кого нет времени на это!

И каждое исправление накапливается из всех предложений в каждом 1-секундном интервале, будь то одно предложение (RMC?), или 8 предложений (GGA, GLL, RMC, GSV*3, GSA и VTG). В NeoGPS подсчет исправлений эквивалентен подсчету секунд.

Примечание: Если вам нужен сверхточный 5-секундный интервал, рассмотрите возможность использования пин-код PPS, если таковой имеется.

В этом эскизе местное время вычисляется правильно, даже если сдвиг часового пояса переходит в новый час, день, месяц или год. Ваш эскиз не пересекает границы дня правильно. 5.5 часовая смена, если я правильно прочитал ваш эскиз. Должен ли я упомянуть, что NeoGPS меньше, быстрее и точнее, чем все другие библиотеки? :) Он доступен из менеджера библиотек Arduino IDE, в меню Sketch - > Include Library - > Manage Библиотеки .

Вы также должны рассмотреть возможность использования чего-то помимо SoftwareSerial. Это очень неэффективно, потому что он отключает прерывания на длительные периоды времени. Это может повлиять на другие части вашего эскиза или на другие библиотеки.

Лучшая библиотека последовательных портов программного обеспечения-AltSoftSerial. Если вы можете переключиться на контакты 8 и 9, я настоятельно рекомендую сделать это.

Если вы не можете переключать контакты (вы действительно уверены?), вы должны использовать мойNeoSWSerial . Это работает на любых двух булавках, и почти так же эффективно. Он поддерживает скорость передачи данных 9600 бод, которую вы используете.