Как я могу получить список стека вызовов в Perl?

Question

Как я могу получить список стека вызовов в Perl?

есть ли способ получить доступ (для распечатки) к списку sub + модуля к произвольной глубине подзвонков, предшествующих текущей позиции в скрипте Perl?

Мне нужно внести изменения в некоторые модули Perl (. pm). рабочий процесс инициируется с веб-страницы через CGI-скрипт, передавая ввод через несколько модулей / объектов, заканчивающихся в модуле, где мне нужно использовать данные. Где-то по ходу дела данные изменились, и мне нужно выяснить, где.

768 7

perl stack-trace callstack

7 ответов:

Comments

Ничего не найдено.

Ovid · Accepted Answer · 2008-10-23 11:59:56

можно использовать Devel:: StackTrace.
use Devel::StackTrace;
my $trace = Devel::StackTrace->new;
print $trace->as_string; # like carp
Он ведет себя, как след карповых, но вы можете получить больше контроля над кадрами.

одна проблема заключается в том, что ссылки строковые и если ссылочное значение изменяется, вы не увидите его. Тем не менее, вы можете на скорую руку некоторые вещи с PadWalker чтобы распечатать полные данные (это было бы огромным, хотя).

Leon Timmermans · Accepted Answer · 2008-10-23 12:01:26

caller может сделать это, хотя вы можете хотеть даже больше информации, чем это.

Axeman · Accepted Answer · 2010-03-23 18:01:26

Carp::longmess будет делать то, что вы хотите, и это стандарт.

use Carp qw<longmess>;
use Data::Dumper;
sub A { &B; }
sub B { &C; }
sub C { &D; }
sub D { &E; }

sub E { 
    # Uncomment below if you want to see the place in E
    # local $Carp::CarpLevel = -1; 
    my $mess = longmess();
    print Dumper( $mess );
}

A();
__END__
$VAR1 = ' at - line 14
    main::D called at - line 12
    main::C called at - line 10
    main::B called at - line 8
    main::A() called at - line 23
';

Я придумал эту суб (теперь с дополнительным благословляющим действием!)

my $stack_frame_re = qr{
    ^                # Beginning of line
    \s*              # Any number of spaces
    ( [\w:]+ )       # Package + sub
    (?: [(] ( .*? ) [)] )? # Anything between two parens
    \s+              # At least one space
    called [ ] at    # "called" followed by a single space
    \s+ ( \S+ ) \s+  # Spaces surrounding at least one non-space character
    line [ ] (\d+)   # line designation
}x;

sub get_stack {
    my @lines = split /\s*\n\s*/, longmess;
    shift @lines;
    my @frames
        = map { 
              my ( $sub_name, $arg_str, $file, $line ) = /$stack_frame_re/;
              my $ref =  { sub_name => $sub_name
                         , args     => [ map { s/^'//; s/'$//; $_ } 
                                         split /\s*,\s*/, $arg_str 
                                       ]
                         , file     => $file
                         , line     => $line 
                         };
              bless $ref, $_[0] if @_;
              $ref
          } 
          @lines
       ;
    return wantarray ? @frames : \@frames;
}

jkramer · Accepted Answer · 2008-10-23 12:53:32

там же Carp::confess и Carp::cluck.

15

2008-10-23 12:53:32

Thariama · Accepted Answer · 2017-10-27 11:39:15

этот код работает без каких-либо дополнительных модулей. Просто включите его там, где это необходимо.
my $i = 1;
print STDERR "Stack Trace:\n";
while ( (my @call_details = (caller($i++))) ){
    print STDERR $call_details[1].":".$call_details[2]." in function ".$call_details[3]."\n";
}

Pat · Accepted Answer · 2008-10-23 12:01:40

хотя это не ответ на ваш вопрос, это может помочь вам решить ваши проблемы :-)

вот интересная статья, описывающая один из способов, как выяснить, кто изменяет переменные Марк Доминус

user2291758 · Accepted Answer · 2014-07-18 13:28:55

тот, что красивее:Devel:: PrettyTrace
use Devel::PrettyTrace;
bt;