Как создать пустой файл в Emacs?

Question

Как создать пустой файл в Emacs?

Как я могу создать пустой файл из emacs, в идеале из буфера dired?

например, я только что открыл модуль Python в режиме dired, создал новый каталог, открыл его в dired, и теперь нужно добавить пустой __init__.py файл в каталоге.

Если я использую C-x C-f __init__.py RET C-x C-s тогда emacs не создает файл, потому что в него не было внесено никаких изменений. Мне нужно будет ввести файл, сохранить его, удалить мой ввод, а затем сохранить его снова для этого работа.

спасибо

585 15

emacs file elisp

15 ответов:

Comments

Ничего не найдено.

phils · Accepted Answer · 2013-09-19 05:49:44

вот адаптация dired-create-directory. Он работает так же, как и простое имя файла, вы также можете указать новые родительские каталоги (которые будут созданы в текущем каталоге) для файла (например,foo/bar/filename).

(eval-after-load 'dired
  '(progn
     (define-key dired-mode-map (kbd "C-c n") 'my-dired-create-file)
     (defun my-dired-create-file (file)
       "Create a file called FILE.
If FILE already exists, signal an error."
       (interactive
        (list (read-file-name "Create file: " (dired-current-directory))))
       (let* ((expanded (expand-file-name file))
              (try expanded)
              (dir (directory-file-name (file-name-directory expanded)))
              new)
         (if (file-exists-p expanded)
             (error "Cannot create file %s: file exists" expanded))
         ;; Find the topmost nonexistent parent dir (variable `new')
         (while (and try (not (file-exists-p try)) (not (equal new try)))
           (setq new try
                 try (directory-file-name (file-name-directory try))))
         (when (not (file-exists-p dir))
           (make-directory dir t))
         (write-region "" nil expanded t)
         (when new
           (dired-add-file new)
           (dired-move-to-filename))))))

Dani · Accepted Answer · 2013-09-18 19:55:39

вы можете использовать сенсорную команду:
M-! touch __init__.py RET

slu · Accepted Answer · 2010-04-08 21:57:50

следующие работы:
C-x b __init__.py RET C-x C-w RET
Если вы находитесь в буфере dired, файл будет сохранен в каталоге, показанном здесь.

фокус в том, чтобы сначала создать пустой буфер при переключении на имя, которое не существует. Затем выпишите файл.

Kilian Foth · Accepted Answer · 2015-05-13 03:17:41

Если вы хотите, чтобы Emacs обрабатывал все новые файлы как измененные, вы можете автоматизировать решение следующим образом:
(add-hook 'find-file-hooks 'assume-new-is-modified)
(defun assume-new-is-modified ()
  (when (not (file-exists-p (buffer-file-name)))
    (set-buffer-modified-p t)))

Vatine · Accepted Answer · 2010-04-07 15:03:50

Emacs не позволит вам сохранить буфер, если он не считает, что содержимое изменилось. Самый быстрый, хотя, возможно, не самый чистый, чтобы открыть файл с помощью C-x C-f, затем нажмите (скажем) пробел и backspace, то вы должны быть в состоянии сохранить файл без содержимого.

есть и другие способы изменения флага "буфер был изменен", но я не думаю, что это проще.

Joao Tavora · Accepted Answer · 2015-05-06 23:19:13

программно и без какой-либо зависимости от touch, это очень просто:
(with-temp-buffer (write-file "path/to/empty/file/"))

Uchenna Nwanyanwu · Accepted Answer · 2012-08-16 18:36:51

используйте команду касания.
M-! touch __init__.py RET

thanhpk · Accepted Answer · 2016-12-02 04:45:42

кратчайший путь

м-!> __init__.pyRET

4

2016-12-02 04:45:42

Squidly · Accepted Answer · 2012-08-16 18:33:29

(shell-command (concat "touch " (buffer-file-name))) будет делать то, что вы хотите, если вы уже открыли пустой файл.

Mirzhan Irkegulov · Accepted Answer · 2014-03-18 12:34:25

В дополнение к другим ответам на странице, вы можете использовать f.el's функция f-touch:

M -:(f-touch "__init__.py")RET

Tino · Accepted Answer · 2018-08-02 07:43:14

после этого потока Emacs добавил две новые команды:

make-empty-file

дирэд-создать пустой файл

эти команды будут доступны в выпуске emacs 27.1.

Ian Mackinnon · Accepted Answer · 2013-12-05 14:18:31

Вы можете пометить пустой буфер измененной под управлением set-buffer-modified-p. Затем, когда вы сохраните его, Emacs запишет файл.
M-;                         ; Eval
(set-buffer-modified-p t)   ; Mark modified
C-x C-s                     ; Save buffer

jenesaisquoi · Accepted Answer · 2018-03-08 19:25:16

Я использую следующую привязку к t в dired.

(defun my-dired-touch (filename)
  (interactive (list (read-string "Filename: " ".gitkeep")))
  (with-temp-buffer
    (write-file filename)))

;; optionally bind it in dired
(with-eval-after-load 'dired
  (define-key dired-mode-map "t" 'my-dired-touch))

alex_koval · Accepted Answer · 2013-08-06 10:52:33

Я изменил ответ от MrBones и создал пользовательскую функцию с привязкой клавиш:
; create empty __init__.py at the place
(defun create-empty-init-py()
  (interactive)
  (shell-command "touch __init__.py")
)
(global-set-key (kbd "C-c p i") 'create-empty-init-py)
Это очень полезно, чтобы не тратить время на повторяющиеся действия создания init.py везде в новой папке проекта Python.

Marcin Antczak · Accepted Answer · 2016-03-25 15:07:12

лучшим вариантом будет:
(with-temp-file "filename"
  (insert ""))