Как сбросить последовательность в Oracle?

In PostgreSQL, Я могу сделать что-то вроде этого:



ALTER SEQUENCE serial RESTART WITH 0;


есть ли в Oracle аналог?

1536   17  

17 ответов:

вот хорошая процедура для сброса любой последовательности в 0 от Oracle guru Тома Кайт. Широкая дискуссия о плюсах и минусах в ссылках ниже тоже.

[email protected]> 
create or replace
procedure reset_seq( p_seq_name in varchar2 )
is
    l_val number;
begin
    execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_val;

    execute immediate
    'alter sequence ' || p_seq_name || ' increment by -' || l_val || 
                                                          ' minvalue 0';

    execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_val;

    execute immediate
    'alter sequence ' || p_seq_name || ' increment by 1 minvalue 0';
end;
/

на этой странице: динамический SQL для сброса значения последовательности
Еще одна хорошая дискуссия также здесь:как сбросить последовательности?

133  
2008-09-18 18:34:52

истинный перезапуск невозможен насколько я знаю. (Пожалуйста, поправьте меня, если я ошибаюсь!).

однако, если вы хотите установить его в 0, вы можете просто удалить ее и создать заново.

Если вы хотите установить его на определенное значение, вы можете установить приращение к отрицательному значению и получить следующее значение.

то есть, если ваша последовательность равна 500, вы можете установить ее на 100 через

ALTER SEQUENCE serial INCREMENT BY -400;
SELECT serial.NEXTVAL FROM dual;
ALTER SEQUENCE serial INCREMENT BY 1;
77  
2017-06-23 21:14:06

Это мой подход:

  1. падение последовательности
  2. воссоздать его

пример:

--Drop sequence

DROP SEQUENCE MY_SEQ;

-- Create sequence 

create sequence MY_SEQ
minvalue 1
maxvalue 999999999999999999999
start with 1
increment by 1
cache 20;
43  
2012-04-08 17:17:09

мой подход является крошечным расширением Dougman это!--5-->.

расширения...

передать значение в качестве параметра. Зачем? Мне нравится называть вещи сброс последовательности обратно в максимальный идентификатор, используемый в некоторой таблице. Я в конечном итоге вызываю этот proc из другого скрипта, который выполняет несколько вызовов для целой группы последовательностей, сбрасывая nextval обратно до некоторого уровня, который достаточно высок, чтобы не вызывать нарушения первичного ключа где я использую значение последовательности для уникального идентификатора.

Он также чтит предыдущий minvalue. Это может на самом деле нажмите на следующее значение еще выше при желании p_val или существующее minvalue превышают текущие или расчетные значения.

лучше всего, он может быть вызван для сброса к указанному значению, и просто подождите, пока вы не увидите обертку " fix all my sequences конец.

create or replace
procedure Reset_Sequence( p_seq_name in varchar2, p_val in number default 0)
is
  l_current number := 0;
  l_difference number := 0;
  l_minvalue user_sequences.min_value%type := 0;

begin

  select min_value
  into l_minvalue
  from user_sequences
  where sequence_name = p_seq_name;

  execute immediate
  'select ' || p_seq_name || '.nextval from dual' INTO l_current;

  if p_Val < l_minvalue then
    l_difference := l_minvalue - l_current;
  else
    l_difference := p_Val - l_current;
  end if;

  if l_difference = 0 then
    return;
  end if;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by ' || l_difference || 
       ' minvalue ' || l_minvalue;

  execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_difference;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by 1 minvalue ' || l_minvalue;
end Reset_Sequence;

эта процедура полезна сама по себе, но теперь давайте добавим еще один, который вызывает ее и задает все программно с Соглашением об именовании последовательности и ищет максимальное значение, используемое в существующей таблице/поле...

create or replace
procedure Reset_Sequence_to_Data(
  p_TableName varchar2,
  p_FieldName varchar2
)
is
  l_MaxUsed NUMBER;
BEGIN

  execute immediate
    'select coalesce(max(' || p_FieldName || '),0) from '|| p_TableName into l_MaxUsed;

  Reset_Sequence( p_TableName || '_' || p_Fieldname || '_SEQ', l_MaxUsed );

END Reset_Sequence_to_Data;

Теперь мы готовим с газом!

описанная выше процедура проверяет максимальное значение поля в таблице, строит имя последовательности из пары таблица / поле и вызывает "Reset_Sequence" с этим чувствовалось максимальное значение.

последняя часть в этой головоломке и глазурь на торте идет дальше...

create or replace
procedure Reset_All_Sequences
is
BEGIN

  Reset_Sequence_to_Data( 'ACTIVITYLOG', 'LOGID' );
  Reset_Sequence_to_Data( 'JOBSTATE', 'JOBID' );
  Reset_Sequence_to_Data( 'BATCH', 'BATCHID' );

END Reset_All_Sequences;

в моей фактической базе данных есть около ста других последовательностей, сбрасываемых через этот механизм, так что есть еще 97 вызовов Reset_Sequence_to_Data в этой процедуре.

любовь ли это? Ненавижу это? Безразлично?

33  
2017-05-23 14:55:07 
alter sequence serial restart start with 0;

Это новая функция в Oracle 12С. Это не входит в официальная документация. Я нашел его в скриптах, созданных пакетом Oracle DBMS_METADATA_DIFF.

предупреждение: я использовал эту функцию несколько раз в производственных системах, и, на мой взгляд, это нормально использовать эту команду в специальных скриптах. Но вы можете не захотеть включать его в процедуру как часть приложения. Я создал Oracle Service Request спрашивает об этой функции; это не просто ошибка документации, это неподдерживаемая функция. Возможно, команда когда-нибудь исчезнет, например WM_CONCAT. (Хотя я думаю, что это маловероятно - синтаксис Oracle редко исчезает, и это простая функция, внутренне по крайней мере в двух местах.)

21  
2018-01-03 21:49:03

следующий скрипт устанавливает последовательность в нужное значение:

учитывая недавно созданную последовательность с именем PCS_PROJ_KEY_SEQ и таблицу PCS_PROJ:

BEGIN
   DECLARE
      PROJ_KEY_MAX       NUMBER := 0;
      PROJ_KEY_CURRVAL   NUMBER := 0;
   BEGIN

    SELECT MAX (PROJ_KEY) INTO PROJ_KEY_MAX FROM PCS_PROJ;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY ' || PROJ_KEY_MAX;
    SELECT PCS_PROJ_KEY_SEQ.NEXTVAL INTO PROJ_KEY_CURRVAL FROM DUAL;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY 1';

END;
END;
/
9  
2012-04-08 17:18:58

этой хранимая процедура перезагрузки моя последовательность:

Create or Replace Procedure Reset_Sequence  
  is
  SeqNbr Number;
begin
   /*  Reset Sequence 'seqXRef_RowID' to 0    */
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by - ' || TO_CHAR(SeqNbr) ;
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by 1';
END;

/

5  
2012-04-08 17:16:21

есть еще один способ сбросить последовательность в Oracle: установите maxvalue и cycle свойства. Когда nextval из последовательности попадает в maxvalue, если cycle свойство устанавливается, то он будет начинаться снова с minvalue последовательности.

преимущество этого метода по сравнению с установкой отрицательный increment by последовательность может продолжать использоваться во время выполнения процесса сброса, уменьшая вероятность того, что вам нужно принять какую-то форму отключения, чтобы сделать сброс.

значение maxvalue должно быть больше, чем текущий nextval, поэтому процедура ниже включает в себя необязательный параметр, позволяющий буфер в случае, если последовательность снова доступна между выбором nextval в процедуре и настройке cycle собственность.

create sequence s start with 1 increment by 1;

select s.nextval from dual
connect by level <= 20;

   NEXTVAL
----------
         1 
...
        20

create or replace procedure reset_sequence ( i_buffer in pls_integer default 0)
as
  maxval pls_integer;
begin

  maxval := s.nextval + greatest(i_buffer, 0); --ensure we don't go backwards!
  execute immediate 'alter sequence s cycle minvalue 0 maxvalue ' || maxval;
  maxval := s.nextval;
  execute immediate 'alter sequence s nocycle maxvalue 99999999999999';

end;
/
show errors

exec reset_sequence;

select s.nextval from dual;

   NEXTVAL
----------
         1

процедура как стоит на месте позволяет возможность того, что другой сеанс будет получать значение 0, которое может или не может быть проблемой для вас. Если это так, вы могли бы всегда:

  • Set minvalue 1 в первом alter
  • исключить второй nextval fetch
  • переместите оператор, чтобы установить nocycle свойство в другую процедуру, которая будет запущена позже (при условии, что вы хотите это сделать).
4  
2013-02-10 19:09:03

1) Предположим, что вы создаете последовательность, как показано ниже:

CREATE SEQUENCE TESTSEQ
INCREMENT BY 1
MINVALUE 1
MAXVALUE 500
NOCACHE
NOCYCLE
NOORDER

2) Теперь вы получаете значения из последовательности. Допустим, я получил четыре раза, как показано ниже.

SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual

3) После выполнения выше четырех команд значение последовательности будет 4. Теперь предположим, что я снова сбросил значение последовательности до 1. Выполните следующие действия. Выполните все действия в том же порядке, как показано на рисунке ниже:

  1. ALTER SEQUENCE TESTSEQ INCREMENT BY -3;
  2. SELECT TESTSEQ.NEXTVAL FROM dual
  3. ALTER SEQUENCE TESTSEQ INCREMENT BY 1;
  4. SELECT TESTSEQ.NEXTVAL FROM dual
2  
2011-02-14 19:30:31

изменение значения приращения последовательности, увеличение его, а затем изменение его обратно довольно безболезненно, плюс у вас есть дополнительное преимущество в том, что вам не нужно восстанавливать все гранты, как если бы вы сбросили/воссоздали последовательность.

2  
2012-04-08 17:15:39

Я создаю блок для сброса всех моих последовательностей:

DECLARE
    I_val number;
BEGIN
    FOR US IN
        (SELECT US.SEQUENCE_NAME FROM USER_SEQUENCES US)
    LOOP
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by -' || l_val || ' minvalue 0';
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by 1 minvalue 0';
    END LOOP;
END;
2  
2015-06-04 22:08:46

вот более надежная процедура для изменения следующего значения, возвращаемого последовательностью, а также многое другое.

  • во-первых, он защищает от атак SQL-инъекций, поскольку ни одна из переданных строк не используется для непосредственного создания каких-либо динамических операторов SQL,
  • во-вторых, это предотвращает следующее значение последовательности от установки за пределами минимальных или максимальных значений последовательности. Элемент next_value будет != min_value и между min_value и max_value.
  • в-третьих, он принимает текущие (или предложенных) increment_by настройка, а также все другие настройки последовательности во внимание при очистке.
  • четвертый все параметры, кроме первого, являются необязательными и, если не указано, принимают текущую настройку последовательности по умолчанию. Если необязательные параметры не указаны, действие не выполняется.
  • наконец, если вы попытаетесь изменить последовательность, которая не существует (или не принадлежит текущему пользователю), она вызовет ORA-01403: no data found ошибка.

вот код:

CREATE OR REPLACE PROCEDURE alter_sequence(
    seq_name      user_sequences.sequence_name%TYPE
  , next_value    user_sequences.last_number%TYPE := null
  , increment_by  user_sequences.increment_by%TYPE := null
  , min_value     user_sequences.min_value%TYPE := null
  , max_value     user_sequences.max_value%TYPE := null
  , cycle_flag    user_sequences.cycle_flag%TYPE := null
  , cache_size    user_sequences.cache_size%TYPE := null
  , order_flag    user_sequences.order_flag%TYPE := null)
  AUTHID CURRENT_USER
AS
  l_seq user_sequences%rowtype;
  l_old_cache user_sequences.cache_size%TYPE;
  l_next user_sequences.min_value%TYPE;
BEGIN
  -- Get current sequence settings as defaults
  SELECT * INTO l_seq FROM user_sequences WHERE sequence_name = seq_name;

  -- Update target settings
  l_old_cache := l_seq.cache_size;
  l_seq.increment_by := nvl(increment_by, l_seq.increment_by);
  l_seq.min_value    := nvl(min_value, l_seq.min_value);
  l_seq.max_value    := nvl(max_value, l_seq.max_value);
  l_seq.cycle_flag   := nvl(cycle_flag, l_seq.cycle_flag);
  l_seq.cache_size   := nvl(cache_size, l_seq.cache_size);
  l_seq.order_flag   := nvl(order_flag, l_seq.order_flag);

  IF next_value is NOT NULL THEN
    -- Determine next value without exceeding limits
    l_next := LEAST(GREATEST(next_value, l_seq.min_value+1),l_seq.max_value);

    -- Grab the actual latest seq number
    EXECUTE IMMEDIATE
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY 1'
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number-l_old_cache)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
    EXECUTE IMMEDIATE 
      'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
    INTO l_seq.last_number;

    l_next := l_next-l_seq.last_number-1;

    -- Reset the sequence number
    IF l_next <> 0 THEN
      EXECUTE IMMEDIATE 
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY '||l_next
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
      EXECUTE IMMEDIATE 
        'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
      INTO l_next;
    END IF;
  END IF;

  -- Prepare Sequence for next use.
  IF COALESCE( cycle_flag
             , next_value
             , increment_by
             , min_value
             , max_value
             , cache_size
             , order_flag) IS NOT NULL
  THEN
    EXECUTE IMMEDIATE 
      'ALTER SEQUENCE '||l_seq.sequence_name
          || ' INCREMENT BY '||l_seq.increment_by
          || ' MINVALUE '||l_seq.min_value
          || ' MAXVALUE '||l_seq.max_value
          || CASE l_seq.cycle_flag
             WHEN 'Y' THEN ' CYCLE' ELSE ' NOCYCLE' END
          || CASE l_seq.cache_size
             WHEN 0 THEN ' NOCACHE'
             ELSE ' CACHE '||l_seq.cache_size END
          || CASE l_seq.order_flag
             WHEN 'Y' THEN ' ORDER' ELSE ' NOORDER' END;
  END IF;
END;
2  
2015-08-14 22:32:49

в моем проекте, как только случилось, что кто-то вручную ввел записи без использования последовательности, поэтому я должен сбросить значение последовательности вручную, для чего я написал ниже фрагмент кода sql:

declare
max_db_value number(10,0);
cur_seq_value number(10,0);
counter number(10,0);
difference number(10,0);
dummy_number number(10);

begin

-- enter table name here
select max(id) into max_db_value from persons;
-- enter sequence name here
select last_number into cur_seq_value from user_sequences where  sequence_name = 'SEQ_PERSONS';

difference  := max_db_value - cur_seq_value;

 for counter in 1..difference
 loop
    -- change sequence name here as well
    select SEQ_PERSONS.nextval into dummy_number from dual;
 end loop;
end;

обратите внимание, что приведенный выше код будет работать, если последовательность отстает.

2  
2015-09-29 08:25:27

Jezus, все это программирование только для перезапуска индекса... Возможно, я идиот, но для pre-oracle 12 (который имеет функцию перезапуска), что не так с simpel:

drop sequence blah;
create sequence blah

?

2  
2017-04-25 18:08:49

вы можете использовать опцию цикла, показанную ниже:

CREATE SEQUENCE test_seq
MINVALUE 0
MAXVALUE 100
START WITH 0
INCREMENT BY 1
CYCLE;

в этом случае, когда последовательность достигает MAXVALUE (100), она будет перерабатываться в MINVALUE (0).

в случае декрементируется последовательность, последовательность будет перерабатывать до МАКСВЕЛЛОВУ.

1  
2014-03-25 17:51:05

вот как сделать все последовательности автоматического приращения соответствуют фактическим данным:

  1. создайте процедуру для применения следующего значения, как уже было описано в этом потоке:

    CREATE OR REPLACE PROCEDURE Reset_Sequence(
    P_Seq_Name IN VARCHAR2,
    P_Val      IN NUMBER DEFAULT 0)
IS
  L_Current    NUMBER                      := 0;
  L_Difference NUMBER                      := 0;
  L_Minvalue User_Sequences.Min_Value%Type := 0;
BEGIN
  SELECT Min_Value
  INTO L_Minvalue
  FROM User_Sequences
  WHERE Sequence_Name = P_Seq_Name;
  EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Current;
  IF P_Val        < L_Minvalue THEN
    L_Difference := L_Minvalue - L_Current;
  ELSE
    L_Difference := P_Val - L_Current;
  END IF;
  IF L_Difference = 0 THEN
    RETURN;
  END IF;
  EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by ' || L_Difference || ' minvalue ' || L_Minvalue;
  EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Difference;
  EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by 1 minvalue ' || L_Minvalue;
END Reset_Sequence;

  2. создайте другую процедуру для согласования всех последовательностей с фактическим содержимым:

    CREATE OR REPLACE PROCEDURE RESET_USER_SEQUENCES_TO_DATA
IS
  STMT CLOB;
BEGIN
  SELECT 'select ''BEGIN'' || chr(10) || x || chr(10) || ''END;'' FROM (select listagg(x, chr(10)) within group (order by null) x FROM ('
    || X
    || '))'
  INTO STMT
  FROM
    (SELECT LISTAGG(X, ' union ') WITHIN GROUP (
    ORDER BY NULL) X
    FROM
      (SELECT CHR(10)
        || 'select ''Reset_Sequence('''''
        || SEQ_NAME
        || ''''','' || coalesce(max('
        || COL_NAME
        || '), 0) || '');'' x from '
        || TABLE_NAME X
      FROM
        (SELECT TABLE_NAME,
          REGEXP_SUBSTR(WTEXT, 'NEW\.(\S*) IS NULL',1,1,'i',1) COL_NAME,
          REGEXP_SUBSTR(BTEXT, '(\.|\s)([a-z_]*)\.nextval',1,1,'i',2) SEQ_NAME
        FROM USER_TRIGGERS
        LEFT JOIN
          (SELECT NAME BNAME,
            TEXT BTEXT
          FROM USER_SOURCE
          WHERE TYPE = 'TRIGGER'
          AND UPPER(TEXT) LIKE '%NEXTVAL%'
          )
        ON BNAME = TRIGGER_NAME
        LEFT JOIN
          (SELECT NAME WNAME,
            TEXT WTEXT
          FROM USER_SOURCE
          WHERE TYPE = 'TRIGGER'
          AND UPPER(TEXT) LIKE '%IS NULL%'
          )
        ON WNAME             = TRIGGER_NAME
        WHERE TRIGGER_TYPE   = 'BEFORE EACH ROW'
        AND TRIGGERING_EVENT = 'INSERT'
        )
      )
    ) ;
  EXECUTE IMMEDIATE STMT INTO STMT;
  --dbms_output.put_line(stmt);
  EXECUTE IMMEDIATE STMT;
END RESET_USER_SEQUENCES_TO_DATA;

Примечания:

  1. процедура извлекает имена из кода триггера и не зависит от соглашений об именах
  2. чтобы проверить сгенерированный код перед выполнением, переключите комментарии на последние две строки
1  
2017-06-23 09:45:39

Я делаю альтернативу, что пользователю не нужно знать значения, система получает и использует переменные для обновления.

--Atualizando sequence da tabela SIGA_TRANSACAO, pois está desatualizada
DECLARE
 actual_sequence_number INTEGER;
 max_number_from_table INTEGER;
 difference INTEGER;
BEGIN
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number FROM DUAL;
 SELECT MAX([nome_da_coluna]) INTO max_number_from_table FROM [nome_da_tabela];
 SELECT (max_number_from_table-actual_sequence_number) INTO difference FROM DUAL;
IF difference > 0 then
 EXECUTE IMMEDIATE CONCAT('alter sequence [nome_da_sequence] increment by ', difference);
 --aqui ele puxa o próximo valor usando o incremento necessário
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number from dual;
--aqui volta o incremento para 1, para que futuras inserções funcionem normalmente
 EXECUTE IMMEDIATE 'ALTER SEQUENCE [nome_da_sequence] INCREMENT by 1';
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] foi atualizada.');
ELSE
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] NÃO foi atualizada, já estava OK!');
END IF;
END;
0  
2017-09-13 13:26:19

Comments

    Ничего не найдено.
Click here to cancel reply.