Как вы тестируете время выполнения кода VBA?

Question

Как вы тестируете время выполнения кода VBA?

есть ли код в VBA, который я могу обернуть функцией, что позволит мне узнать время, необходимое для запуска, чтобы я мог сравнить различные времена работы функций?

697 5

performance profiling optimization testing vba

5 ответов:

Comments

Ничего не найдено.

Mike Woodhouse · Accepted Answer · 2012-10-11 11:20:11

если ваши функции не очень медленные, вам понадобится таймер с очень высоким разрешением. Самый точный, который я знаю, это QueryPerformanceCounter. Google это для получения дополнительной информации. Попробуйте вставить следующее В класс, назовите его CTimer скажем, тогда вы можете сделать экземпляр где-то глобальный и просто позвонить .StartCounter и .TimeElapsed
Option Explicit

Private Type LARGE_INTEGER
    lowpart As Long
    highpart As Long
End Type

Private Declare Function QueryPerformanceCounter Lib "kernel32" (lpPerformanceCount As LARGE_INTEGER) As Long
Private Declare Function QueryPerformanceFrequency Lib "kernel32" (lpFrequency As LARGE_INTEGER) As Long

Private m_CounterStart As LARGE_INTEGER
Private m_CounterEnd As LARGE_INTEGER
Private m_crFrequency As Double

Private Const TWO_32 = 4294967296# ' = 256# * 256# * 256# * 256#

Private Function LI2Double(LI As LARGE_INTEGER) As Double
Dim Low As Double
    Low = LI.lowpart
    If Low < 0 Then
        Low = Low + TWO_32
    End If
    LI2Double = LI.highpart * TWO_32 + Low
End Function

Private Sub Class_Initialize()
Dim PerfFrequency As LARGE_INTEGER
    QueryPerformanceFrequency PerfFrequency
    m_crFrequency = LI2Double(PerfFrequency)
End Sub

Public Sub StartCounter()
    QueryPerformanceCounter m_CounterStart
End Sub

Property Get TimeElapsed() As Double
Dim crStart As Double
Dim crStop As Double
    QueryPerformanceCounter m_CounterEnd
    crStart = LI2Double(m_CounterStart)
    crStop = LI2Double(m_CounterEnd)
    TimeElapsed = 1000# * (crStop - crStart) / m_crFrequency
End Property

dbb · Accepted Answer · 2008-10-14 02:51:56

функция таймера в VBA дает количество секунд прошедших с полуночи, до 1/100 секунды.
Dim t as single
t = Timer
'code
MsgBox Timer - t
Если вам нужно большее разрешение, я бы просто запустил функцию 1000 раз и разделил общее время на 1000.

Kodak · Accepted Answer · 2012-04-23 11:04:25

Если вы пытаетесь вернуть время, как секундомер можно использовать следующие API, который возвращает время в миллисекундах с момента запуска системы:
Public Declare Function GetTickCount Lib "kernel32.dll" () As Long
Sub testTimer()
Dim t As Long
t = GetTickCount

For i = 1 To 1000000
a = a + 1
Next

MsgBox GetTickCount - t, , "Milliseconds"
End Sub
после http://www.pcreview.co.uk/forums/grab-time-milliseconds-included-vba-t994765.html (как timeGetTime в winmm.dll не работал для меня, и QueryPerformanceCounter был слишком сложным для выполнения необходимой задачи)

miodf · Accepted Answer · 2014-03-21 17:41:27

для newbees, эти ссылки объясняет, как сделать автоматическое профилирование всех подводных лодок, которые вы хотите контролировать время:

http://www.nullskull.com/a/1602/profiling-and-optimizing-vba.aspx

http://sites.mcpher.com/share/Home/excelquirks/optimizationlink см. раздел procProfiler.zip in http://sites.mcpher.com/share/Home/excelquirks/downlable-items

Tom Juergens · Accepted Answer · 2008-10-13 22:20:30

мы использовали решение, основанное на timeGetTime в winmm.dll для миллисекундной точности в течение многих лет. См.http://www.aboutvb.de/kom/artikel/komstopwatch.htm

статья на немецком языке, но код в загрузке (класс VBA, обертывающий вызов функции dll) достаточно прост для использования и понимания, не имея возможности прочитать статью.