Как работает этот кусок запутанного кода Хаскелла?

для начала, у нас есть прекрасное определение

x = 1 : map (2*) x

что само по себе немного галлюциногенный, если вы никогда не видели его раньше. Во всяком случае, это довольно стандартный трюк лени и рекурсии. Теперь мы избавимся от явной рекурсии с помощью fix, и точка-бесплатно-ify.

x = fix (\vs -> 1 : map (2*) vs)
x = fix ((1:) . map (2*))

следующее, что мы собираемся сделать, это расширить : раздел и сделать map излишне сложной.

x = fix ((:) 1 . (map . (*) . (*2)) 1)

Ну, теперь у нас есть две копии эта константа 1. Это никогда не будет делать, поэтому мы будем использовать приложение для чтения, чтобы де-дублировать это. Кроме того, композиция функций-это немного мусор, поэтому давайте заменим это на (<$>) везде, где мы можем.

x = fix (liftA2 (.) (:) (map . (*) . (*2)) 1)
x = fix (((.) <$> (:) <*> (map . (*) . (*2))) 1)
x = fix (((<$>) <$> (:) <*> (map <$> (*) <$> (*2))) 1)

далее: этот звонок map слишком читаемым. Но бояться нечего: мы можем использовать законы монады, чтобы немного расширить его. В частности, fmap f x = x >>= return . f, так что

map f x = x >>= return . f
map f x = ((:[]) <$> f) =<< x

мы можем указать-free-ify, заменить (.) С (<$>), а затем добавить некоторые паразитные разделы:

map = (=<<) . ((:[]) <$>)
map = (=<<) <$> ((:[]) <$>)
map = (<$> ((:[]) <$>)) (=<<)

подставляя это уравнение в нашем предыдущем шаге:

x = fix (((<$>) <$> (:) <*> ((<$> ((:[]) <$>)) (=<<) <$> (*) <$> (*2))) 1)

наконец, вы нарушаете пробел и создаете замечательное окончательное уравнение

x=fix(((<$>)<$>(:)<*>((<$>((:[])<$>))(=<<)<$>(*)<$>(*2)))1)