Как конвертировать секунды в ЧЧ: мм:СС с помощью T-SQL

Question

Как конвертировать секунды в ЧЧ: мм:СС с помощью T-SQL

ситуация у вас есть значение в секундах (XXX.XX), и вы хотите конвертировать в HH:MM:SS с помощью T-SQL.

пример:

121.25 s становится 00:02:01.25

1224 11

tsql datetime

11 ответов:

Comments

Ничего не найдено.

great_llama · Accepted Answer · 2009-08-11 23:00:47

вы хотите умножить на миллисекунды, как дробная часть отбрасывается.
SELECT DATEADD(ms, 121.25 * 1000, 0)
Если вы хотите его без части даты вы можете использовать конвертировать, со стилем 114
SELECT CONVERT(varchar, DATEADD(ms, 121.25 * 1000, 0), 114)

jim31415 · Accepted Answer · 2012-06-25 17:27:59

Если объем времени превышает 24 часа он не будет правильно обрабатываться с помощью методов DATEADD и CONVERT.

SELECT CONVERT(varchar, DATEADD(ms, 24*60*60 * 1000, 0), 114)
00:00:00:000

следующая функция будет обрабатывать раз, превышающих 24 часа (~Макс 35,791,394 часов).

create function [dbo].[ConvertTimeToHHMMSS]
(
    @time decimal(28,3), 
    @unit varchar(20)
)
returns varchar(20)
as
begin

    declare @seconds decimal(18,3), @minutes int, @hours int;

    if(@unit = 'hour' or @unit = 'hh' )
        set @seconds = @time * 60 * 60;
    else if(@unit = 'minute' or @unit = 'mi' or @unit = 'n')
        set @seconds = @time * 60;
    else if(@unit = 'second' or @unit = 'ss' or @unit = 's')
        set @seconds = @time;
    else set @seconds = 0; -- unknown time units

    set @hours = convert(int, @seconds /60 / 60);
    set @minutes = convert(int, (@seconds / 60) - (@hours * 60 ));
    set @seconds = @seconds % 60;

    return 
        convert(varchar(9), convert(int, @hours)) + ':' +
        right('00' + convert(varchar(2), convert(int, @minutes)), 2) + ':' +
        right('00' + convert(varchar(6), @seconds), 6)

end

использование:

select dbo.ConvertTimeToHHMMSS(123, 's')
select dbo.ConvertTimeToHHMMSS(96.999, 'mi')
select dbo.ConvertTimeToHHMMSS(35791394.999, 'hh')
0:02:03.000
1:36:59.940
35791394:59:56.400

BrettC · Accepted Answer · 2014-10-13 22:14:49

для тех, кто имеет проблемы с использованием DATEADD и конвертировать в течение секунд, превышающих 24 часа, мы можем использовать модуль, чтобы обойти это:
SELECT CONVERT(varchar, @seconds / 86400 ) + ':' + -- Days
CONVERT(varchar, DATEADD(ms, ( @seconds % 86400 ) * 1000, 0), 114)
as "Converted to D:HH:MM:SS.MS"

cmd.prompt · Accepted Answer · 2014-02-06 21:04:46

DECLARE @seconds AS int = 896434;
SELECT
    CONVERT(varchar, (@seconds / 86400))                --Days
    + ':' +
    CONVERT(varchar, DATEADD(ss, @seconds, 0), 108);    --Hours, Minutes, Seconds

выходы:

10:09:00:34

Pranesh Janarthanan · Accepted Answer · 2016-09-19 15:39:37

использование SQL Server 2008

declare @Seconds as int = 3600;
SELECT CONVERT(time(0), DATEADD(SECOND, @Seconds, 0)) as 'hh:mm:ss'

Richard Reddy · Accepted Answer · 2009-08-11 23:00:26

С помощью SQL Server 05 я могу заставить это работать с помощью:
declare @OrigValue int;
set @OrigValue = 121.25;
select replace(str(@OrigValue/3600,len(ltrim(@OrigValue/3600))+abs(sign(@OrigValue/359999)-1)) + ':' + str((@OrigValue/60)%60,2) + ':' + str(@OrigValue%60,2),' ','0')

albin.varghese · Accepted Answer · 2015-06-26 08:06:04

DECLARE @TimeinSecond INT
SET @TimeinSecond = 340 -- Change the seconds
SELECT RIGHT('0' + CAST(@TimeinSecond / 3600 AS VARCHAR),2) + ':' +
RIGHT('0' + CAST((@TimeinSecond / 60) % 60 AS VARCHAR),2)  + ':' +
RIGHT('0' + CAST(@TimeinSecond % 60 AS VARCHAR),2)

AbelianCommuter · Accepted Answer · 2015-06-29 19:36:32

Это то, что я использую (как правило, для отчетов электронной почты таблицы html)
declare @time int, @hms varchar(20)
set @time = 12345
set @hms = cast(cast((@Time)/3600 as int) as varchar(3)) 
  +':'+ right('0'+ cast(cast(((@Time)%3600)/60 as int) as varchar(2)),2) 
  +':'+ right('0'+ cast(((@Time)%3600)%60 as varchar(2)),2) +' (hh:mm:ss)'
select @hms

yacob · Accepted Answer · 2013-10-23 18:06:18

SELECT substring(convert (varchar(23),Dateadd(s,10000,LEFT(getdate(),11)),121),12,8)
10000 - это ваше значение в сек

Rajiv Singh · Accepted Answer · 2017-10-30 08:58:37

DECLARE @Seconds INT = 86200;
SELECT 
CONVERT(VARCHAR(15), 
CAST(CONVERT(VARCHAR(12), @Seconds / 60 / 60 % 24)
+':'+ CONVERT(VARCHAR(2), @Seconds / 60 % 60)
+':'+ CONVERT(VARCHAR(2), @Seconds % 60) AS TIME), 100) AS [HH:MM:SS (AM/PM)]

Bruno · Accepted Answer · 2013-05-24 22:07:24

преобразование секунд в часы в select query:

SELECT field_in_seconds,round((field_in_seconds / 3600),2) FROM a_table;

Это даст вам результат в десятичном формате. Не знаю, как конвертировать 1.50 в 1:30. Пожалуйста, не стесняйтесь редактировать мой код!