Как удалить все файлы и папки в папку на cmd вызов

Question

Как удалить все файлы и папки в папку на cmd вызов

Я использую Windows.

Я хочу удалить все файлы и папки в папку на системный вызов.

Я могу называть так:

>rd /s /q c:destination

>md c:destination

вы знаете более простой способ?

706 9

windows batch-file

9 ответов:

Comments

Ничего не найдено.

Joey · Accepted Answer · 2016-06-22 18:26:51

Нет, я не знаю ни одного.

если вы хотите сохранить исходный каталог по какой-то причине (ACLs, &c.), а вместо этого действительно хотите его очистить, то вы можете сделать следующее:
del /q destination\*
for /d %x in (destination\*) do @rd /s /q "%x"
это сначала удаляет все файлы из директории, а затем рекурсивно удаляет все вложенные каталоги, но в целом сохраняя директории верхнего уровня "как есть" (за исключением содержания).

обратите внимание, что в пакетном файле вам нужно удвоить % внутри for петля:
del /q destination\*
for /d %%x in (destination\*) do @rd /s /q "%%x"

Sean · Accepted Answer · 2012-10-11 22:56:59

del c:\destination\*.* /s /q работал для меня. Я надеюсь, что это работает и для вас.

Banan · Accepted Answer · 2016-03-15 00:02:48

Я думаю, самый простой способ сделать это:
rmdir /s /q "C:\FolderToNotToDelete\"
последнее " \ " в пути является важной частью.

fractor · Accepted Answer · 2014-01-24 12:05:12

если имена вложенных папок могут содержать пробелы, их необходимо заключить в экранированные кавычки. В следующем примере это показано для команд, используемых в пакетном файле.
set targetdir=c:\example
del /q %targetdir%\*
for /d %%x in (%targetdir%\*) do @rd /s /q ^"%%x^"

Rosberg Linhares · Accepted Answer · 2017-02-16 17:00:18

да! Используйте Powershell:
powershell -Command "Remove-Item 'c:\destination\*' -Recurse -Force"

Maxim Suslov · Accepted Answer · 2016-11-10 19:44:39

удалить файл:
del PATH_TO_FILE
удалить папку со всеми файлами в ней:
rmdir /s /q PATH_TO_FOLDER
удалить все файлы из определенной папки (не удаляя саму папку) немного сложнее. del /s *.* не удается удалить папки, но удаляет файлы из всех вложенных папок. Поэтому необходимы две команды:
del /q PATH_TO_FOLDER\*.*
for /d %i in (PATH_TO_FOLDER\*.*) do @rmdir /s /q "%i"
вы можете создать скрипт для удаления всего, что вы хотите (папки или файла), как это mydel.bat:
@echo off
setlocal enableextensions

if "%~1"=="" (
    echo Usage: %0 path
    exit /b 1
)

:: check whether it is folder or file
set ISDIR=0
set ATTR=%~a1
set DIRATTR=%ATTR:~0,1%
if /i "%DIRATTR%"=="d" set ISDIR=1

:: Delete folder or file
if %ISDIR%==1 (rmdir /s /q "%~1") else (del "%~1")
exit /b %ERRORLEVEL%
несколько примеров использование:
mydel.bat "path\to\folder with spaces"
mydel.bat path\to\file_or_folder

BateTech · Accepted Answer · 2014-05-27 18:52:46

один простой однострочный вариант-создать пустой каталог где-то в вашей файловой системе, а затем использовать ROBOCOPY (http://technet.microsoft.com/en-us/library/cc733145.aspx) с /MIR переключатель для удаления всех файлов и вложенных папок. По умолчанию robocopy не копирует безопасность, поэтому списки управления доступом в корневой папке должны оставаться нетронутыми.

также, вероятно, хотите установить значение для переключателя повтора,/r, потому что по умолчанию количество попыток 1 миллион.
robocopy "C:\DoNotDelete_UsedByScripts\EmptyFolder" "c:\temp\MyDirectoryToEmpty" /MIR /r:3

Ynotinc · Accepted Answer · 2014-07-09 00:54:53

У меня была индексная папка с 33 папками, в которых нужно было удалить все файлы и подпапки. Я открыл командную строку в папке индекса, а затем использовал следующие команды:
for /d in (*) do rd /s /q "%a" & (
md "%a")
Я разделил их на две строки (нажмите enter после первой строки, и когда вас попросят добавить вторую строку), потому что если ввести в одну строку, это может не сработать. Эта команда удалит каждый каталог, а затем создаст новый, который будет пустым, тем самым удаляя все файлы и подпапки в каталоге. оригинальный каталог.

Academy of Programmer · Accepted Answer · 2017-03-20 12:18:27

перейдите в родительский каталог

Line1 pushd "родительский каталог"

удалить подпапки

Line2 rd /s / q . 2 > nul

https://superuser.com/questions/173859/how-can-i-delete-all-files-subfolders-in-a-given-folder-via-the-command-prompt