Ранжирование значений на основе другого набора данных в SAS

Один из способов ранжирования по переменной из отдельного набора данных заключается в использовании proc sql'Sкоррелированных подзапросов . По сути, вы подсчитываете количество нижних значений в наборе данных подстановки для каждого значения в данных, подлежащих ранжированию.

proc sql;
    create table want as
    select 
        B.obs_B, 
        (
            select count(distinct A.Var1) + 1
            from A
            where A.var1 <= B.var1.
        ) as var1
    from B;
quit;

Который можно обернуть в макрос. Ниже для записи каждого из подзапросов используется макроцикл. Он просматривает список переменных и параметризует подзапрос по мере необходимости.

%macro rankBy(
        inScore /*Dataset containing data to be ranked*/, 
        inLookup /*Dataset containing data against which to rank*/, 
        varID /*Variable by which to identify an observation*/, 
        varsRank /*Space separated list of variable names to be ranked*/, 
        outData /*Output dataset name*/);
    /* Rank variables in one dataset by identically named variables in another */
    proc sql;
        create table &outData. as
        select 
            scr.&varID.
            /* Loop through each variable to be ranked */
            %do i = 1 %to %sysfunc(countw(&varsRank., %str( )));
                /* Store the variable name in a macro variable */
                %let var = %scan(&varsRank., &i., %str( ));
                /* Rank: count all the rows with lower value in lookup */
                , (
                    select count(distinct lkp&i..&var.) + 1
                    from &inLookup. as lkp&i.
                    where lkp&i..&var. <= scr.&var.
                ) as &var.
            %end;
        from &inScore. as scr;
    quit;
%mend rankBy;

%rankBy(
    inScore = B,
    inLookup = A,
    varID = obs_B,
    varsRank = VAR1 VAR2 VAR3,
    outData = want);

Что касается скорости, то она будет медленной, если ваш A велик, но должен подходить для больших B и малых A.

В грубом тестировании на медленном ПК я увидел:

A: 1e1    B: 1e6    time: ~1s
A: 1e2    B: 1e6    time: ~2s
A: 1e3    B: 1e6    time: ~5s
A: 1e1    B: 1e7    time: ~10s
A: 1e2    B: 1e7    time: ~12s
A: 1e4    B: 1e6    time: ~30s

---

Править: Как Джо указывает ниже, длительность запроса зависит не только от количества наблюдений в наборе данных, но и от того, сколько уникальных значений существует в данных. Очевидно, SAS выполняет оптимизацию, чтобы уменьшить сравнения только до различных значений в B, тем самым уменьшая количество раз элементы в A их нужно пересчитать. Это означает, что если набор данных B содержит большое количество уникальных значений (в переменных ранжирования), то процесс займет значительно больше времени, чем показано на рисунке. Это более вероятно, если ваши данные не являются целыми числами, как показывает Джо.

---

Править: Runtime test rig:

data A;
    input obs_A  VAR1  VAR2  VAR3;
datalines;
1    10    100   2000
2    20    300   1000
3    30    200   4000
4    40    500   3000
5    50    400   5000
;
run;
data B;
    do obs_B = 1 to 1e7;
        VAR1 = ceil(rand("uniform")* 60);
        VAR2 = ceil(rand("uniform")* 500);
        VAR3 = ceil(rand("uniform")* 6000);
        output;
    end;
run;
%let start = %sysfunc(time());
%rankBy(
    inScore = B,
    inLookup = A,
    varID = obs_B,
    varsRank = VAR1 VAR2 VAR3,
    outData = want);
%let time = %sysfunc(putn(%sysevalf(%sysfunc(time()) - &start.), time12.2));
%put &time.;

Вывод:

0:00:12.41