Сортировка списка в Groovy необычным способом

Это должно сделать:

// Define our input list
def list = [ 'Armadillo', 'Cat', 'Dog', 'Cow', 'Zebra', 'Horse', 'Cow' ]

// Define a closure that will do the sorting
def sorter = { String a, String b, List prefixes=[ 'Cat', 'Cow' ] ->
  // Get the index into order for a and b
  // if not found, set to being Integer.MAX_VALUE
  def (aidx,bidx) = [a,b].collect { prefixes.indexOf it }.collect {
    it == -1 ? Integer.MAX_VALUE : it
  }
  // Compare the two indexes.
  // If they are the same, compare alphabetically
  aidx <=> bidx ?: a <=> b
}

// Create a new list by sorting using our closure
def sorted = list.sort false, sorter

// Print it out
println sorted

Что печатает:

[Cat, Cow, Cow, Armadillo, Dog, Horse, Zebra]

Я прокомментировал его, чтобы попытаться объяснить каждый шаг, который он делает. Добавляя элементы префикса по умолчанию в качестве необязательного параметра в закрытии sorter, это означает, что мы можем сделать такие вещи, чтобы изменить значение по умолчанию:

// Use Dog, Zebra, Cow as our prefix items
def dzc = list.sort false, sorter.rcurry( [ 'Dog', 'Zebra', 'Cow' ] )
println dzc

, который затем печатает список, отсортированный следующим образом:

[Dog, Zebra, Cow, Cow, Armadillo, Cat, Horse]

Если у вас нет дубликатов элементов, вы можете попробовать следующее:

def highPriority = [ 'Cat', 'Cow' ]
def list = [ 'Armadillo', 'Dog', 'Cow', 'Zebra', 'Horse', 'Cat' ]
highPriority + list.minus(highPriority).sort()

Вот еще одна альтернатива, которая кажется мне проще:

// smaller values get sorted first
def priority(animal) {
    animal in ['Cat', 'Cow'] ? 0 : 1
}

def list = [ 'Armadillo', 'Cat', 'Dog', 'Cow', 'Zebra', 'Horse', 'Cow' ]

def sorted = list.sort{ a, b -> priority(a) <=> priority(b) ?: a <=> b }

assert sorted == ['Cat', 'Cow', 'Cow', 'Armadillo', 'Dog', 'Horse', 'Zebra']

Вдохновленный ответом Томаса :

def highPriority = [ 'Cat', 'Cow' ]
def list = [ 'Armadillo', 'Cat', 'Dog', 'Cow', 'Zebra', 'Horse', 'Cow' ]

// Group animals by priority.
def groups = list.groupBy { it in highPriority ? it : 'rest' }
// High priority animals are sorted by priority and the rest alphabetically.
def sorted = highPriority.collectMany { groups[it] } + groups['rest'].sort()

assert sorted == ['Cat', 'Cow', 'Cow', 'Armadillo', 'Dog', 'Horse', 'Zebra']

Переменная groups является чем-то вроде [rest:[Armadillo, Dog, Zebra, Horse], Cat:[Cat], Cow:[Cow, Cow]].

Другим, возможно менее надежным, решением может быть:

def sorted = list.sort(false) { 
    def priority = highPriority.indexOf(it)
    if (priority == -1) priority = highPriority.size()
    // Sort first by priority and then by the value itself
    "$priority$it"
}

Он менее надежен в том смысле, что сортируется по строкам типа "2Armadillo", "0Cat", и т. д., и не будет работать, если у вас есть 9 или более высокоприоритетных животных (потому что "10Alpaca" < "9Eel". Было бы здорово, если бы Groovy предоставил какой-то сопоставимый тип кортежей, например Python's tuples , поэтому вместо возврата "$priority$it" в качестве сопоставимого ключ, можно было бы вернуть кортеж (priority, it).

Этот вопрос довольно стар, но сегодня я обнаружил, что у Groovy есть, довольно недокументированный, OrderBy компаратор, который может быть использован в этом случае:

def highPriority = ['Cow', 'Cat']
def list = ['Armadillo', 'Cat', 'Dog', 'Cow', 'Zebra', 'Horse', 'Cow']

def sorted = list.sort new OrderBy([{ -highPriority.indexOf(it) }, { it }])

assert sorted == ['Cat', 'Cow', 'Cow', 'Armadillo', 'Dog', 'Horse', 'Zebra']

Компаратор OrderBy сначала сравнивает животных, используя их индекс в списке highPriority отрицается (поэтому животные, которые не имеют высокого приоритета (т. е. индекс -1), перемещаются в конец списка), и если индексы равны, он сравнивает их с помощью функции идентификации {it}, которая, поскольку животные являются строками, сортирует их по алфавиту.