T-SQL: цикл по массиву известных значений

вот мой сценарий:



Допустим, у меня есть хранимая процедура, в которой мне нужно вызвать другую хранимую процедуру на набор определенных идентификаторов; есть ли способ сделать это?



т. е. вместо того, чтобы сделать это:



exec p_MyInnerProcedure 4

exec p_MyInnerProcedure 7

exec p_MyInnerProcedure 12

exec p_MyInnerProcedure 22

exec p_MyInnerProcedure 19


делать что-то вроде этого:



*magic where I specify my list contains 4,7,12,22,19*



DECLARE my_cursor CURSOR FAST_FORWARD FOR

*magic select*



OPEN my_cursor 

FETCH NEXT FROM my_cursor INTO @MyId

WHILE @@FETCH_STATUS = 0

BEGIN



exec p_MyInnerProcedure @MyId



FETCH NEXT FROM my_cursor INTO @MyId

END


моя главная цель здесь-просто ремонтопригодность (легко удалить/добавить идентификаторы по мере изменения бизнеса), имея возможность перечислить все идентификаторы в одной строке... Производительность не должна быть большая проблема

2005   6  

6 ответов:

declare @ids table(idx int identity(1,1), id int)

insert into @ids (id)
    select 4 union
    select 7 union
    select 12 union
    select 22 union
    select 19

declare @i int
declare @cnt int

select @i = min(idx) - 1, @cnt = max(idx) from @ids

while @i < @cnt
begin
     select @i = @i + 1

     declare @id = select id from @ids where idx = @i

     exec p_MyInnerProcedure @id
end
82  
2009-10-19 18:09:36

то, что я делаю в этом сценарии, - это создать переменную таблицы для хранения идентификаторов.

  Declare @Ids Table (id integer primary Key not null)
  Insert @Ids(id) values (4),(7),(12),(22),(19)

-- (или вызовите другую функцию с табличным значением для создания этой таблицы)

затем цикл на основе строк в этой таблице

  Declare @Id Integer
  While exists (Select * From @Ids)
    Begin
      Select @Id = Min(id) from @Ids
      exec p_MyInnerProcedure @Id 
      Delete from @Ids Where id = @Id
    End

или...

  Declare @Id Integer = 0 -- assuming all Ids are > 0
  While exists (Select * From @Ids
                where id > @Id)
    Begin
      Select @Id = Min(id) 
      from @Ids Where id > @Id
      exec p_MyInnerProcedure @Id 
    End

любой из вышеперечисленных подходов намного быстрее, чем курсор (объявленный против обычных пользовательских таблиц). Табличные переменные имеют плохую репутацию, потому что при неправильном использовании (для очень широких таблиц с большими количество строк) они не являются производительными. Но если вы используете их только для хранения ключевого значения или 4-байтового целого числа, с индексом (как в этом случае) они чрезвычайно быстры.

37  
2017-05-31 18:24:38

используйте статическую переменную курсора и разделить функции:

declare @comma_delimited_list varchar(4000)
set @comma_delimited_list = '4,7,12,22,19'

declare @cursor cursor
set @cursor = cursor static for 
  select convert(int, Value) as Id from dbo.Split(@comma_delimited_list) a

declare @id int
open @cursor
while 1=1 begin
  fetch next from @cursor into @id
  if @@fetch_status <> 0 break
  ....do something....
end
-- not strictly necessary w/ cursor variables since they will go out of scope like a normal var
close @cursor
deallocate @cursor

курсоры имеют плохую репутацию, так как параметры по умолчанию, объявленные для пользовательских таблиц, могут генерировать много накладных расходов.

но в этом случае нагрузка довольно минимальной, меньше, чем любые другие методы. Статический указывает SQL Server материализовать результаты в базе данных tempdb, а затем выполнить итерацию. Для небольших списков, подобных этому, это оптимальное решение.

15  
2016-10-31 02:03:20

обычно я использую следующий подход

DECLARE @calls TABLE (
    id INT IDENTITY(1,1)
    ,parameter INT
    )

INSERT INTO @calls
select parameter from some_table where some_condition -- here you populate your parameters

declare @i int
declare @n int
declare @myId int
select @i = min(id), @n = max(id) from @calls
while @i <= @n
begin
    select 
        @myId = parameter
    from 
        @calls
    where id = @i

        EXECUTE p_MyInnerProcedure @myId
    set @i = @i+1
end
4  
2009-10-19 18:17:40 
CREATE TABLE #ListOfIDs (IDValue INT)

DECLARE @IDs VARCHAR(50), @ID VARCHAR(5)
SET @IDs = @OriginalListOfIDs + ','

WHILE LEN(@IDs) > 1
BEGIN
SET @ID = SUBSTRING(@IDs, 0, CHARINDEX(',', @IDs));
INSERT INTO #ListOfIDs (IDValue) VALUES(@ID);
SET @IDs = REPLACE(',' + @IDs, ',' + @ID + ',', '')
END

SELECT * 
FROM #ListOfIDs
2  
2012-12-11 18:42:31

вы можете попробовать, как показано ниже :

declare @list varchar(MAX), @i int
select @i=0, @list ='4,7,12,22,19,'

while( @i < LEN(@list))
begin
    declare @item varchar(MAX)
    SELECT  @item = SUBSTRING(@list,  @i,CHARINDEX(',',@list,@i)-@i)
    select @item

     --do your stuff here with @item 
     exec p_MyInnerProcedure @item 

    set @i = CHARINDEX(',',@list,@i)+1
    if(@i = 0) set @i = LEN(@list) 
end
2  
2014-07-21 18:15:59

Comments

    Ничего не найдено.
Click here to cancel reply.