В чем разница между хэшем и хэш-ссылкой в Perl?

простой хэш близок к массиву. Их инициализации даже выглядят похожими. Сначала массив:

@last_name = (
  "Ward",   "Cleaver",
  "Fred",   "Flintstone",
  "Archie", "Bunker"
);

теперь представим ту же информацию с хэшем (он же ассоциативный массив):

%last_name = (
  "Ward",   "Cleaver",
  "Fred",   "Flintstone",
  "Archie", "Bunker"
);

хотя они имеют одно и то же имя, массив @last_name и хэш %last_name полностью независимы.

С массивом, если мы хотим знать фамилию Арчи, мы должны выполнить линейный поиск:

my $lname;
for (my $i = 0; $i < @last_name; $i += 2) {
  $lname = $last_name[$i+1] if $last_name[$i] eq "Archie";
}
print "Archie $lname\n";

С хэш, это гораздо более прямой синтаксически:

print "Archie $last_name{Archie}\n";

скажем, мы хотим представить информацию с немного более богатой структурой:

• Кливер (фамилия)
  • прихода (имя)
  • июнь (первый супруг имя)
• Флинстоун
  • Фред
  • Вильма
• бункер
  • Арчи
  • Эдит

до того, как появились ссылки, плоские хэши ключей-значений были лучшими, что мы могли сделать, но ссылки позволяют

my %personal_info = (
    "Cleaver", {
        "FIRST",  "Ward",
        "SPOUSE", "June",
    },
    "Flintstone", {
        "FIRST",  "Fred",
        "SPOUSE", "Wilma",
    },
    "Bunker", {
        "FIRST",  "Archie",
        "SPOUSE", "Edith",
    },
);

внутренне, ключи и значения %personal_info все скаляры, но значения являются особым видом скаляра: хэш ссылки, созданные с помощью {}. Ссылки позволяют моделировать "многомерные" хэши. Например, мы можем добраться до Вильмы через

$personal_info{Flintstone}->{SPOUSE}

обратите внимание, что Perl позволяет нам опускать стрелки между нижними индексами, поэтому вышеизложенное эквивалентно

$personal_info{Flintstone}{SPOUSE}

это много набрав, если вы хотите узнать больше о Фреде, так что вы можете захватить ссылку как своего рода курсор:

$fred = $personal_info{Flintstone};
print "Fred's wife is $fred->{SPOUSE}\n";

, потому что $fred в приведенном выше фрагменте есть hashref, стрелка необходимый. Если вы оставите его, но мудро включен use strict чтобы помочь вам поймать такие ошибки, компилятор будет жаловаться:

Global symbol "%fred" requires explicit package name at ...

ссылки на Perl похожи на указатели в C и C++, но они никогда не могут быть null. Указатели в C и c++ требуют разыменования, а также ссылки в Perl.

параметры функций C и C++ имеют семантику передачи по значению: они просто копии, поэтому модификации не возвращаются к вызывающему объекту. Если вы хотите увидеть изменения, вы надо передать указатель. Вы можете получить этот эффект со ссылками в Perl:

sub add_barney {
    my($personal_info) = @_;

    $personal_info->{Rubble} = {
        FIRST  => "Barney",
        SPOUSE => "Betty",
    };
}

add_barney \%personal_info;

без обратной косой черты,add_barney получил бы копию, которая выбрасывается, как только суб возвращается.

обратите внимание также на использование "жирной запятой" (=>) выше. Он автоматически цитирует строку слева и делает инициализации хэша менее синтаксически шумными.